{
    Copyright (c) 2016 by Free Pascal Development Team

    This unit implements support import, export, link routines
    for the m68k Atari target

    This program is free software; you can redistribute it and/or modify
    it under the terms of the GNU General Public License as published by
    the Free Software Foundation; either version 2 of the License, or
    (at your option) any later version.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this program; if not, write to the Free Software
    Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.

 ****************************************************************************
}
unit t_atari;

{$i fpcdefs.inc}

interface

    uses
      rescmn, comprsrc, link;

type
  PLinkerAtari = ^TLinkerAtari;
  TLinkerAtari = class(texternallinker)
    private
      UseVLink: boolean;
      function WriteResponseFile(isdll: boolean): boolean;
      procedure SetAtariInfo;
      function MakeAtariExe: boolean;
    public
      constructor Create; override;
      procedure SetDefaultInfo; override;
      procedure InitSysInitUnitName; override;
      function  MakeExecutable: boolean; override;
  end;


implementation

    uses
       sysutils,cutils,cfileutl,cclasses,aasmbase,
       globtype,globals,systems,verbose,cscript,fmodule,i_atari;


constructor TLinkerAtari.Create;
begin
  UseVLink:=(cs_link_vlink in current_settings.globalswitches);

  Inherited Create;
  { allow duplicated libs (PM) }
  SharedLibFiles.doubles:=true;
  StaticLibFiles.doubles:=true;
end;


procedure TLinkerAtari.SetAtariInfo;
begin
  with Info do
   begin
    if not UseVLink then
     begin
      ExeCmd[1]:='ld $DYNLINK $FLAGS $OPT $STRIP $MAP -d -n -o $EXE -T $RES';
     end
    else
     begin
      ExeCmd[1]:='vlink -b '+ataritos_exe_format+' $FLAGS $GCSECTIONS $OPT $STRIP $MAP -o $EXE -T $RES';
     end;
   end;
end;


procedure TLinkerAtari.SetDefaultInfo;
begin
  if target_info.system = system_m68k_Atari then
    SetAtariInfo;
end;


procedure TLinkerAtari.InitSysInitUnitName;
begin
  sysinitunit:='si_prc';
end;


function TLinkerAtari.WriteResponseFile(isdll: boolean): boolean;
var
  linkres  : TLinkRes;
  i        : longint;
  HPath    : TCmdStrListItem;
  s        : string;
  linklibc : boolean;
begin
  WriteResponseFile:=False;

  { Open link.res file }
  LinkRes:=TLinkRes.Create(outputexedir+Info.ResName,true);
  if UseVLink and (source_info.dirsep <> '/') then
    LinkRes.fForceUseForwardSlash:=true;

  { Write path to search libraries }
  HPath:=TCmdStrListItem(current_module.locallibrarysearchpath.First);
  while assigned(HPath) do
   begin
    s:=HPath.Str;
    if (cs_link_on_target in current_settings.globalswitches) then
     s:=ScriptFixFileName(s);
    LinkRes.Add('-L'+s);
    HPath:=TCmdStrListItem(HPath.Next);
   end;
  HPath:=TCmdStrListItem(LibrarySearchPath.First);
  while assigned(HPath) do
   begin
    s:=HPath.Str;
    if s<>'' then
     LinkRes.Add('SEARCH_DIR("'+s+'")');
    HPath:=TCmdStrListItem(HPath.Next);
   end;

  if not UseVLink then
   begin
    LinkRes.Add('SECTIONS');
    LinkRes.Add('{');
    LinkRes.Add('  .text 0xe4:');
    LinkRes.Add('  {');
    LinkRes.Add('    CREATE_OBJECT_SYMBOLS');
    LinkRes.Add('    *(.text)');
    LinkRes.Add('    CONSTRUCTORS');
    LinkRes.Add('    _etext = .;');
    LinkRes.Add('    __etext = .;');
    LinkRes.Add('  }');
    LinkRes.Add('  .data :');
    LinkRes.Add('  {');
    LinkRes.Add('    *(.data)');
    LinkRes.Add('    _edata = .;');
    LinkRes.Add('    __edata = .;');
    LinkRes.Add('  }');
    LinkRes.Add('  .bss :');
    LinkRes.Add('  {');
    LinkRes.Add('    __bss_start = .;');
    LinkRes.Add('    *(.bss)');
    LinkRes.Add('    *(COMMON)');
    LinkRes.Add('    _end = .;');
    LinkRes.Add('    __end = .;');
    LinkRes.Add('  }');
    LinkRes.Add('}');
   end;
  if (UseVLink) and (ataritos_exe_format = 'aoutmint') then
   begin
    LinkRes.Add('SECTIONS {');
    LinkRes.Add('  . = 0xe4;');
    LinkRes.Add('  .text: {');
    LinkRes.Add('    *(.i* i* I*)');
    LinkRes.Add('    *(.t* t* T* .c* c* CODE*)');
    LinkRes.Add('    *(.f* f* F*)');
    LinkRes.Add('    _etext = .;');
    LinkRes.Add('    __etext = .;');
    LinkRes.Add('    . = ALIGN(4);');
    LinkRes.Add('  }');
    LinkRes.Add('  .data: {');
    LinkRes.Add('    PROVIDE(_LinkerDB = . + 0x8000);');
    LinkRes.Add('    PROVIDE(_SDA_BASE_ = . + 0x8000);');
    LinkRes.Add('    VBCC_CONSTRUCTORS');
    LinkRes.Add('    *(.rodata*)');
    LinkRes.Add('    *(.d* d* D*)');
    LinkRes.Add('    *(.sdata*)');
    LinkRes.Add('    *(__MERGED)');
    LinkRes.Add('    _edata = .;');
    LinkRes.Add('    __edata = .;');
    LinkRes.Add('    . = ALIGN(4);');
    LinkRes.Add('  }');
    LinkRes.Add('  .bss: {');
    LinkRes.Add('    *(.sbss*)');
    LinkRes.Add('    *(.scommon)');
    LinkRes.Add('    *(.b* b* B* .u* u* U*)');
    LinkRes.Add('    *(COMMON)');
    LinkRes.Add('    _end = ALIGN(4);');
    LinkRes.Add('    __end = ALIGN(4);');
    LinkRes.Add('  }');
    LinkRes.Add('}');;
   end;

  LinkRes.Add('INPUT (');
  { add objectfiles, start with prt0 always }
  if not (target_info.system in systems_internal_sysinit) then
    begin
      s:=FindObjectFile('prt0','',false);
      LinkRes.AddFileName(maybequoted(s));
    end;
  while not ObjectFiles.Empty do
   begin
    s:=ObjectFiles.GetFirst;
    if s<>'' then
     begin
      { vlink doesn't use SEARCH_DIR for object files }
      if UseVLink then
       s:=FindObjectFile(s,'',false);
      LinkRes.AddFileName(maybequoted(s));
     end;
   end;

  { Write staticlibraries }
  if not StaticLibFiles.Empty then
   begin
     { vlink doesn't need, and doesn't support GROUP }
    if not UseVLink then
     begin
      LinkRes.Add(')');
      LinkRes.Add('GROUP(');
     end;
    while not StaticLibFiles.Empty do
     begin
      S:=StaticLibFiles.GetFirst;
      LinkRes.AddFileName(maybequoted(s));
     end;
   end;

  if not UseVLink then
   begin
    LinkRes.Add(')');

    { Write sharedlibraries like -l<lib>, also add the needed dynamic linker
      here to be sure that it gets linked this is needed for glibc2 systems (PFV) }
    linklibc:=false;
    while not SharedLibFiles.Empty do
     begin
      S:=SharedLibFiles.GetFirst;
      if s<>'c' then
       begin
        i:=Pos(target_info.sharedlibext,S);
        if i>0 then
         Delete(S,i,255);
        LinkRes.Add('-l'+s);
       end
      else
       begin
        LinkRes.Add('-l'+s);
        linklibc:=true;
       end;
     end;
    { be sure that libc&libgcc is the last lib }
    if linklibc then
     begin
      LinkRes.Add('-lc');
      LinkRes.Add('-lgcc');
     end;
   end
  else
   begin
    while not SharedLibFiles.Empty do
     begin
      S:=SharedLibFiles.GetFirst;
      LinkRes.Add('lib'+s+target_info.staticlibext);
     end;
    LinkRes.Add(')');
   end;

{ Write and Close response }
  linkres.writetodisk;
  linkres.free;

  WriteResponseFile:=True;
end;


function TLinkerAtari.MakeAtariExe: boolean;
var
  BinStr,
  CmdStr  : TCmdStr;
  StripStr: string[40];
  DynLinkStr : ansistring;
  GCSectionsStr : string;
  FlagsStr : string;
  MapStr: string;
  ExeName: string;
begin
  StripStr:='';
  GCSectionsStr:='';
  DynLinkStr:='';
  MapStr:='';
  if UseVLink then
    FlagsStr:='-tos-flags '+tostr(ataritos_exe_flags)
  else
    FlagsStr:='--mprg-flags '+tostr(ataritos_exe_flags);

  if (cs_link_map in current_settings.globalswitches) then
    if UseVLink then
      MapStr:='-M'+maybequoted(ScriptFixFileName(current_module.mapfilename))
    else
      MapStr:='-Map '+maybequoted(ScriptFixFileName(current_module.mapfilename));
  if (cs_link_strip in current_settings.globalswitches) then
    StripStr:='-s';
  if rlinkpath<>'' then
    DynLinkStr:='--rpath-link '+rlinkpath;
  if UseVLink then
    begin
      if create_smartlink_sections then
        GCSectionsStr:='-gc-all -sc';
    end;

  ExeName:=current_module.exefilename;

  { Call linker }
  SplitBinCmd(Info.ExeCmd[1],BinStr,CmdStr);
  binstr:=FindUtil(utilsprefix+BinStr);
  Replace(cmdstr,'$OPT',Info.ExtraOptions);
  Replace(cmdstr,'$EXE',maybequoted(ScriptFixFileName(ExeName)));
  Replace(cmdstr,'$RES',maybequoted(ScriptFixFileName(outputexedir+Info.ResName)));
  Replace(cmdstr,'$MAP',MapStr);
  Replace(cmdstr,'$FLAGS',FlagsStr);
  Replace(cmdstr,'$STRIP',StripStr);
  Replace(cmdstr,'$GCSECTIONS',GCSectionsStr);
  Replace(cmdstr,'$DYNLINK',DynLinkStr);

  MakeAtariExe:=DoExec(BinStr,CmdStr,true,false);
end;


function TLinkerAtari.MakeExecutable:boolean;
var
  success : boolean;
begin
  if not(cs_link_nolink in current_settings.globalswitches) then
    Message1(exec_i_linking,current_module.exefilename);

  { Write used files and libraries }
  WriteResponseFile(false);

  success:=MakeAtariExe;

  { Remove ReponseFile }
  if (success) and not(cs_link_nolink in current_settings.globalswitches) then
    DeleteFile(outputexedir+Info.ResName);

  MakeExecutable:=success;   { otherwise a recursive call to link method }
end;




{*****************************************************************************
                                     Initialize
*****************************************************************************}

initialization
  RegisterLinker(ld_atari,TLinkerAtari);
  RegisterTarget(system_m68k_atari_info);
end.