mirror of
https://gitlab.com/freepascal.org/fpc/source.git
synced 2026-01-10 00:04:14 +01:00
9ce34c63c9
Every startup code must now provide an additional entry point called "_dynamic_start" that is set as new the entry point if the program links to a Pascal shared library. Its purpose is to set up an exit hook usually passed via a register, which should be called during program finalization if non-nil. We use this additional entry point because this register only has meaningful content when there are any compile-time linked shared libraries, otherwise it often contains random garbage. The difference between the _dynamic_start and the original code is minimal; actually in all implementations the _dynamic_start code passes on control to the old startup code, so we use an additional entry point instead of an additional startup file. Detailed changes and fixes list: compiler: always link to the dynamic loader (ld.so) when compiling shared libraries. Fixes crashes in the loader during shared library finalization on some Linuxes remove additional ENTRY() section in arm linker script select either _dynamic_start or _start as entry point depending on whether this is a static or dynamic executable powerpc*: do not set System.isLibrary in startup code, it will be set during library initialization anyway trap in case of reaching code locations that should not be reached instead of looping (possibly endlessly) powerpc: register atexit() function pointer if supplied to the executable and call it during shutdown correctly set argc/argv/envp in shared library code and return correctly to the caller after initialization pass on exitcode in shared library haltproc use the more recent exit_group system call if available for shutdown powerpc64 fix .ptrgl stub, do not set the environment register to the value of the GOT entry in the function descriptor arm do not set System.isLibrary in startup code, it will be set during library initialization anyway reload exitcode to pass to shutdown mips,mipsel,sparc added stubs to allow correct linking git-svn-id: trunk@19036 -
118 lines
3.3 KiB
ActionScript
118 lines
3.3 KiB
ActionScript
#
|
|
# This file is part of the Free Pascal run time library.
|
|
# Copyright (c) 2002 by Florian Klaempfl
|
|
# members of the Free Pascal development team.
|
|
#
|
|
# See the file COPYING.FPC, included in this distribution,
|
|
# for details about the copyright.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY;without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
#
|
|
#**********************************************************************}
|
|
#
|
|
# Linux ELF startup code for Free Pascal
|
|
#
|
|
|
|
/* This is the canonical entry point, usually the first thing in the text
|
|
segment. The document "System V Application Binary Interface AMD64
|
|
Architecture Processor Supplement Version 0.99.5" pg. 30 defines that
|
|
the entry point runs, most registers' values are unspecified, except
|
|
for:
|
|
|
|
%rdx Contains a function pointer to be registered with `atexit'.
|
|
This is how the dynamic linker arranges to have DT_FINI
|
|
functions called for shared libraries that have been loaded
|
|
before this code runs.
|
|
|
|
%rsp The stack contains the arguments and environment:
|
|
0(%rsp) argc
|
|
8(%rsp) argv[0]
|
|
...
|
|
(8*argc)(%rsp) NULL
|
|
(8*(argc+1))(%rsp) envp[0]
|
|
...
|
|
NULL
|
|
*/
|
|
|
|
.text
|
|
.globl _dynamic_start
|
|
.type _dynamic_start,@function
|
|
_dynamic_start:
|
|
movq __dl_fini@GOTPCREL(%rip),%rax
|
|
movq %rdx,(%rax)
|
|
jmp _start
|
|
|
|
.text
|
|
.globl _start
|
|
.type _start,@function
|
|
_start:
|
|
popq %rsi /* Pop the argument count. */
|
|
movq operatingsystem_parameter_argc@GOTPCREL(%rip),%rax
|
|
movq %rsi,(%rax)
|
|
movq operatingsystem_parameter_argv@GOTPCREL(%rip),%rax
|
|
movq %rsp,(%rax) /* argv starts just at the current stack top. */
|
|
leaq 8(,%rsi,8),%rax
|
|
addq %rsp,%rax
|
|
movq operatingsystem_parameter_envp@GOTPCREL(%rip),%rcx
|
|
movq %rax,(%rcx)
|
|
andq $~15,%rsp /* Align the stack to a 16 byte boundary to follow the ABI. */
|
|
|
|
/* Save initial stackpointer */
|
|
movq __stkptr@GOTPCREL(%rip),%rax
|
|
movq %rsp,(%rax)
|
|
|
|
xorq %rbp, %rbp
|
|
call PASCALMAIN
|
|
jmp _haltproc
|
|
|
|
.globl _haltproc
|
|
.type _haltproc,@function
|
|
_haltproc:
|
|
movq __dl_fini@GOTPCREL(%rip),%rax
|
|
movq (%rax),%rax
|
|
testq %rax,%rax
|
|
jz .LNoDlFiniCall
|
|
call *%rax
|
|
.LNoDlFiniCall:
|
|
|
|
movq operatingsystem_result@GOTPCREL(%rip),%rax
|
|
movzwl (%rax),%edi
|
|
movl $231,%eax /* exit_group call */
|
|
syscall
|
|
jmp _haltproc
|
|
|
|
/* Define a symbol for the first piece of initialized data. */
|
|
.data
|
|
.globl __data_start
|
|
__data_start:
|
|
.long 0
|
|
.weak data_start
|
|
data_start = __data_start
|
|
|
|
.bss
|
|
.comm __stkptr,8
|
|
.comm __dl_fini,8
|
|
|
|
.comm operatingsystem_parameter_envp,8
|
|
.comm operatingsystem_parameter_argc,8
|
|
.comm operatingsystem_parameter_argv,8
|
|
|
|
|
|
/* We need this stuff to make gdb behave itself, otherwise
|
|
gdb will chokes with SIGILL when trying to debug apps.
|
|
*/
|
|
.section ".note.ABI-tag", "a"
|
|
.align 4
|
|
.long 1f - 0f
|
|
.long 3f - 2f
|
|
.long 1
|
|
0: .asciz "GNU"
|
|
1: .align 4
|
|
2: .long 0
|
|
.long 2,4,0
|
|
3: .align 4
|
|
|
|
.section .note.GNU-stack,"",@progbits
|