mirror of
https://gitlab.com/freepascal.org/fpc/source.git
synced 2026-01-05 15:30:31 +01:00
9ce34c63c9
Every startup code must now provide an additional entry point called "_dynamic_start" that is set as new the entry point if the program links to a Pascal shared library. Its purpose is to set up an exit hook usually passed via a register, which should be called during program finalization if non-nil. We use this additional entry point because this register only has meaningful content when there are any compile-time linked shared libraries, otherwise it often contains random garbage. The difference between the _dynamic_start and the original code is minimal; actually in all implementations the _dynamic_start code passes on control to the old startup code, so we use an additional entry point instead of an additional startup file. Detailed changes and fixes list: compiler: always link to the dynamic loader (ld.so) when compiling shared libraries. Fixes crashes in the loader during shared library finalization on some Linuxes remove additional ENTRY() section in arm linker script select either _dynamic_start or _start as entry point depending on whether this is a static or dynamic executable powerpc*: do not set System.isLibrary in startup code, it will be set during library initialization anyway trap in case of reaching code locations that should not be reached instead of looping (possibly endlessly) powerpc: register atexit() function pointer if supplied to the executable and call it during shutdown correctly set argc/argv/envp in shared library code and return correctly to the caller after initialization pass on exitcode in shared library haltproc use the more recent exit_group system call if available for shutdown powerpc64 fix .ptrgl stub, do not set the environment register to the value of the GOT entry in the function descriptor arm do not set System.isLibrary in startup code, it will be set during library initialization anyway reload exitcode to pass to shutdown mips,mipsel,sparc added stubs to allow correct linking git-svn-id: trunk@19036 -
142 lines
3.6 KiB
ActionScript
142 lines
3.6 KiB
ActionScript
/* Startup code for ARM & ELF
|
|
Copyright (C) 1995, 1996, 1997, 1998, 2001, 2002 Free Software Foundation, Inc.
|
|
This file is part of the GNU C Library.
|
|
|
|
The GNU C Library is free software; you can redistribute it and/or
|
|
modify it under the terms of the GNU Lesser General Public
|
|
License as published by the Free Software Foundation; either
|
|
version 2.1 of the License, or (at your option) any later version.
|
|
|
|
The GNU C Library is distributed in the hope that it will be useful,
|
|
but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
Lesser General Public License for more details.
|
|
|
|
You should have received a copy of the GNU Lesser General Public
|
|
License along with the GNU C Library; if not, write to the Free
|
|
Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
|
|
02111-1307 USA. */
|
|
|
|
/* This is the canonical entry point, usually the first thing in the text
|
|
segment.
|
|
|
|
Note that the code in the .init section has already been run.
|
|
This includes _init and _libc_init
|
|
|
|
|
|
At this entry point, most registers' values are unspecified, except:
|
|
|
|
a1 Contains a function pointer to be registered with `atexit'.
|
|
This is how the dynamic linker arranges to have DT_FINI
|
|
functions called for shared libraries that have been loaded
|
|
before this code runs.
|
|
|
|
sp The stack contains the arguments and environment:
|
|
0(sp) argc
|
|
4(sp) argv[0]
|
|
...
|
|
(4*argc)(sp) NULL
|
|
(4*(argc+1))(sp) envp[0]
|
|
...
|
|
NULL
|
|
*/
|
|
|
|
.text
|
|
.globl _dynamic_start
|
|
.type _dynamic_start,#function
|
|
_dynamic_start:
|
|
ldr ip,=__dl_fini
|
|
str a1,[ip]
|
|
b _start
|
|
|
|
.text
|
|
.globl _start
|
|
.type _start,#function
|
|
_start:
|
|
/* Clear the frame pointer since this is the outermost frame. */
|
|
mov fp, #0
|
|
ldmia sp!, {a2}
|
|
|
|
/* Pop argc off the stack and save a pointer to argv */
|
|
ldr ip,=operatingsystem_parameter_argc
|
|
ldr a3,=operatingsystem_parameter_argv
|
|
str a2,[ip]
|
|
|
|
/* calc envp */
|
|
add a2,a2,#1
|
|
add a2,sp,a2,LSL #2
|
|
ldr ip,=operatingsystem_parameter_envp
|
|
|
|
str sp,[a3]
|
|
str a2,[ip]
|
|
|
|
/* Save initial stackpointer */
|
|
ldr ip,=__stkptr
|
|
str sp,[ip]
|
|
/* align sp again to 8 byte boundary, needed by eabi */
|
|
sub sp,sp,#4
|
|
|
|
/* Let the libc call main and exit with its return code. */
|
|
bl PASCALMAIN
|
|
|
|
.globl _haltproc
|
|
.type _haltproc,#function
|
|
_haltproc:
|
|
/* r0 contains exitcode */
|
|
swi 0x900001
|
|
b _haltproc
|
|
|
|
.globl _haltproc_eabi
|
|
.type _haltproc_eabi,#function
|
|
_haltproc_eabi:
|
|
ldr r0,=__dl_fini
|
|
ldr r0,[r0]
|
|
cmp r0,#0
|
|
|
|
/* only branch if not equal zero */
|
|
movne lr,pc
|
|
bxne r0 /* we require armv5 anyway, so use bx here */
|
|
|
|
.Lloop:
|
|
ldr r0,=operatingsystem_result
|
|
ldr r0,[r0]
|
|
mov r7,#248 /* exit group call */
|
|
swi 0x0
|
|
b .Lloop
|
|
|
|
/* Define a symbol for the first piece of initialized data. */
|
|
.data
|
|
.globl __data_start
|
|
__data_start:
|
|
.long 0
|
|
.weak data_start
|
|
data_start = __data_start
|
|
|
|
.bss
|
|
.comm __dl_fini,4
|
|
.comm __stkptr,4
|
|
|
|
.comm operatingsystem_parameter_envp,4
|
|
.comm operatingsystem_parameter_argc,4
|
|
.comm operatingsystem_parameter_argv,4
|
|
|
|
.section ".comment"
|
|
.byte 0
|
|
.ascii "generated by FPC http://www.freepascal.org\0"
|
|
|
|
/* We need this stuff to make gdb behave itself, otherwise
|
|
gdb will chokes with SIGILL when trying to debug apps.
|
|
*/
|
|
.section ".note.ABI-tag", "a"
|
|
.align 4
|
|
.long 1f - 0f
|
|
.long 3f - 2f
|
|
.long 1
|
|
0: .asciz "GNU"
|
|
1: .align 4
|
|
2: .long 0
|
|
.long 2,0,0
|
|
3: .align 4
|
|
|
|
.section .note.GNU-stack,"",%progbits
|