mirror of
https://gitlab.com/freepascal.org/fpc/source.git
synced 2025-10-18 06:01:41 +02:00
0ad1a26c61
startup for Linux/i386 (since the code generator won't keep the 16 byte
alignment (yet?) for that platform, it won't make much difference in
practice)
git-svn-id: trunk@22383 -
144 lines
4.0 KiB
ActionScript
144 lines
4.0 KiB
ActionScript
#
|
|
# This file is part of the Free Pascal run time library.
|
|
# Copyright (c) 1999-2000 by Michael Van Canneyt and Peter Vreman
|
|
# members of the Free Pascal development team.
|
|
#
|
|
# See the file COPYING.FPC, included in this distribution,
|
|
# for details about the copyright.
|
|
#
|
|
# This program is distributed in the hope that it will be useful,
|
|
# but WITHOUT ANY WARRANTY;without even the implied warranty of
|
|
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
#
|
|
#**********************************************************************}
|
|
#
|
|
# Linux ELF startup code for Free Pascal
|
|
#
|
|
|
|
.file "prt1.as"
|
|
.text
|
|
.globl _start
|
|
.type _start,@function
|
|
_start:
|
|
/* First locate the start of the environment variables */
|
|
popl %esi
|
|
|
|
movl %esp,%ebx /* Points to the arguments */
|
|
movl %esi,%eax
|
|
incl %eax
|
|
shll $2,%eax
|
|
addl %esp,%eax
|
|
andl $0xfffffff0,%esp /* Align stack to 16 bytes */
|
|
|
|
movl %eax,operatingsystem_parameter_envp /* Move the environment pointer */
|
|
movl %esi,operatingsystem_parameter_argc /* Move the argument counter */
|
|
movl %ebx,operatingsystem_parameter_argv /* Move the argument pointer */
|
|
|
|
xorl %ebp,%ebp
|
|
pushl %eax /* __libc_start_main takes 7 arguments -> push 1 extra to keep 16 byte stack alignment */
|
|
pushl %esp
|
|
pushl %edx
|
|
pushl $_fini_dummy
|
|
pushl $_init_dummy
|
|
pushl %ebx
|
|
pushl %esi
|
|
pushl $cmain
|
|
call __libc_start_main
|
|
hlt
|
|
|
|
/* fake main routine which will be run from libc */
|
|
cmain:
|
|
/* save return address */
|
|
popl %eax
|
|
movl %eax,___fpc_ret
|
|
movl %ebx,___fpc_ret_ebx
|
|
movl %esi,___fpc_ret_esi
|
|
movl %edi,___fpc_ret_edi
|
|
pushl %eax
|
|
|
|
/* align stack to 16 bytes before call */
|
|
subl $12, %esp
|
|
|
|
call __gmon_start__
|
|
|
|
/* restore stack */
|
|
addl $12, %esp
|
|
|
|
/* Save initial stackpointer */
|
|
movl %esp,__stkptr
|
|
|
|
/* start the program (jmp to keep stack alignment) */
|
|
jmp PASCALMAIN
|
|
hlt
|
|
|
|
.globl _haltproc
|
|
.type _haltproc,@function
|
|
_haltproc:
|
|
movzwl operatingsystem_result,%eax
|
|
|
|
movl ___fpc_ret,%edx /* return to libc */
|
|
movl ___fpc_ret_ebx,%ebx
|
|
movl ___fpc_ret_esi,%esi
|
|
movl ___fpc_ret_edi,%edi
|
|
push %edx
|
|
_init_dummy:
|
|
_fini_dummy:
|
|
ret
|
|
|
|
.globl __gmon_start__
|
|
.type __gmon_start__,@function
|
|
__gmon_start__:
|
|
pushl %ebp
|
|
movl __monstarted,%eax
|
|
leal 0x1(%eax),%edx
|
|
movl %esp,%ebp
|
|
movl %edx,__monstarted
|
|
testl %eax,%eax
|
|
jnz .Lnomonstart
|
|
pushl $etext /* Initialize gmon */
|
|
pushl $_start
|
|
call monstartup
|
|
addl $8,%esp
|
|
pushl $_mcleanup
|
|
call atexit
|
|
addl $4,%esp
|
|
.Lnomonstart:
|
|
movl %ebp,%esp
|
|
popl %ebp
|
|
ret
|
|
|
|
.data
|
|
.align 4
|
|
|
|
___fpc_ret: /* return address to libc */
|
|
.long 0
|
|
___fpc_ret_ebx:
|
|
.long 0
|
|
___fpc_ret_esi:
|
|
.long 0
|
|
___fpc_ret_edi:
|
|
.long 0
|
|
|
|
.bss
|
|
.lcomm __monstarted,4
|
|
|
|
.type __stkptr,@object
|
|
.size __stkptr,4
|
|
.global __stkptr
|
|
__stkptr:
|
|
.skip 4
|
|
|
|
.type operatingsystem_parameters,@object
|
|
.size operatingsystem_parameters,12
|
|
operatingsystem_parameters:
|
|
.skip 3*4
|
|
|
|
.global operatingsystem_parameter_envp
|
|
.global operatingsystem_parameter_argc
|
|
.global operatingsystem_parameter_argv
|
|
.set operatingsystem_parameter_envp,operatingsystem_parameters+0
|
|
.set operatingsystem_parameter_argc,operatingsystem_parameters+4
|
|
.set operatingsystem_parameter_argv,operatingsystem_parameters+8
|
|
|
|
.section .note.GNU-stack,"",%progbits
|